有更简单的方法吗？是的，使用zip元运算符Z与infix结合使用，但是

my @islands = $islands_A[] Z[but] $islands_N[];

你为什么不修改数组来改变格式？

把调用。str在它得到的值上，say调用. gist

如果您希望put输出一些特定的文本，请确保。Str方法输出该文本。

不过，我不认为您真的想要输出该格式。我认为您希望say输出该格式。那是因为say是供人类理解的，而您希望它对人类更好。

当你有一个“拉库能做X”的问题时，答案是不变的，是的，这只是工作量的问题，以及那时你是否还会称之为拉库。

你真正想问的问题是做X有多容易。

我去实现了你提供的那个链接。

请注意，这只是我在睡觉前创建的一个快速实现。所以把这看作是第一个草稿。

如果我真的要这么做，我可能会把它扔掉，在花了几天时间学习足够的R来弄清楚它实际上在做什么之后重新开始。

class NamedVec does Positional does Associative {
  has @.names is List;
  has @.nums is List handles <sum>;
  has %!kv is Map;

  class Partial {
    has $.name;
    has $.num;
  }

  submethod TWEAK {
    %!kv := %!kv.new: @!names Z=> @!nums;
  }

  method from-pairlist ( +@pairs ) {
    my @names;
    my @nums;
    for @pairs -> (:$key, :$value) {
      push @names, $key;
      push @nums, $value;
    }
    self.new: :@names, :@nums
  }

  method from-list ( +@list ){
    my @names;
    my @nums;
    for @list -> (:$name, :$num) {
      push @names, $name;
      push @nums, $num;
    }
    self.new: :@names, :@nums
  }

  method gist () {
    my @widths = @!names».chars Zmax @!nums».chars;
    sub infix:<fmt> ( $str, $width is copy ){
      $width -= $str.chars;
      my $l = $width div 2;
      my $r = $width - $l;
      (' ' x $l) ~ $str ~ (' ' x $r)
    }
    (@!names Zfmt @widths) ~ "\n" ~ (@!nums Zfmt @widths)
  }

  method R-str () {
    chomp qq :to/END/
    Named num [1:@!nums.elems()] @!nums[]
     - attr(*, "names")= chr [1:@!names.elems()] @!names.map(*.raku)
    END
  }

  method of () {}
  method AT-POS ( $i ){
    Partial.new: name => @!names[$i], num => @!nums[$i]
  }
  method AT-KEY ( $name ){
    Partial.new: :$name, num => %!kv{$name}
  }
}

multi sub postcircumfix:<{ }> (NamedVec:D $v, Str:D $name){
  $v.from-list: callsame
}
multi sub postcircumfix:<{ }> (NamedVec:D $v, List \l){
  $v.from-list: callsame
}
 

my $islands_A = <11506,5500,16988,2968,16,184,23,280,84,73,25,43,21,82,3745,840,13,30,30,89,40,33,49,14,42,227,16,36,29,15,306,44,58,43,9390,32,13,29,6795,16,15,183,14,26,19,13,12,82>.split(","); #Area
my $islands_N = <<"Africa" "Antarctica" "Asia" "Australia" "Axel Heiberg" "Baffin" "Banks" "Borneo" "Britain" "Celebes" "Celon" "Cuba" "Devon" "Ellesmere" "Europe" "Greenland" "Hainan" "Hispaniola" "Hokkaido" "Honshu" "Iceland" "Ireland" "Java" "Kyushu" "Luzon" "Madagascar" "Melville" "Mindanao" "Moluccas" "New Britain" "New Guinea" "New Zealand (N)" "New Zealand (S)" "Newfoundland" "North America" "Novaya Zemlya" "Prince of Wales" "Sakhalin" "South America" "Southampton" "Spitsbergen" "Sumatra" "Taiwan" "Tasmania" "Tierra del Fuego" "Timor" "Vancouver" "Victoria">>; 

# either will work
#my $islands = NamedVec.from-pairlist( $islands_N[] Z=> $islands_A[] );
my $islands = NamedVec.new( names => $islands_N, nums => $islands_A );

put $islands.R-str;

say $islands<Asia Africa Antarctica>;

say $islands.sum;