你好，我需要用处理制作一些小部件，为此我正在考虑用PGraphics的自定义子类将它们包装在一起。然后我就可以拖动它们了。
目前的问题是，如何获取PGraphics对象的位置？
PGraphics widg;
void setup(){
widg=createGraphics(50,50);
drawWidg();
image(widg,10,10);
}
void draw(){
}
void mouseClicked(){
//PGraphics doesn't have x, y properties. How to get the position of widg?
if(mouseX-widg.x>0 && mouseX-widg.x<widg.width && mouseY-widg.y>0 && mouseY-widg.y<widg.height){
println("clicked!");
}
}
void drawWidg(){
widg.beginDraw();
...
widg.endDraw();
}
PGrapical实际上没有坐标，但你必须使用一些来显示它，对吗？所以这些是你的坐标。在上面的代码中，它们将是（10,10），与PGrapics宽度/高度一起调用image（）时使用。
鼠标按下的代码是：
void mouseClicked(){
if(mouseX > 10 && mouseX < 10 + widg.width &&
mouseY > 10 && mouseX < 10+ widg.height){
println("clicked!");
}
}
现在这不是很好。因为它有那些硬数字。所以为了避免这种情况，你可以使用PVector来存储这些位置，比如：
PGraphics widg;
PVector widgCoord;
void setup(){
widgCoord = new PVector(10, 10);
widg=createGraphics(50, 50);
drawWidg();
image(widg,widgCoord.x, widgCoord.y);
}
void draw(){
}
void mouseClicked(){
if(mouseX > widgCoord.x && mouseX < widgCoord.x + widg.width &&
mouseY > widgCoord.y && mouseX < widgCoord.y + widg.height){
println("clicked!");
}
}
void drawWidg(){
widg.beginDraw();
widg.background(255,0,0);
widg.endDraw();
}
或者，正如您所提到的，您可以使用PGraphics、PVector和您需要的其他内容创建一个Widget类。类似于：
Widget one;
void setup() {
one = new Widget(10, 10, 50, 50);
one.drawWidg();
}
void draw() {
background(0);
one.display();
}
void mouseClicked() {
if (one.isOver()) {
println("clicked!");
}
}
class Widget {
PGraphics widg;
PVector wCoord;
color c = color(255, 0, 0);
Widget(float x, float y, int w, int h) {
wCoord = new PVector(x, y);
widg = createGraphics(w, h);
}
void drawWidg() {
widg.beginDraw();
widg.background(c);
widg.endDraw();
}
void display() {
image (widg, wCoord.x, wCoord.y);
}
boolean isOver() {
return mouseX > wCoord.x && mouseX < wCoord.x + widg.width &&
mouseY > wCoord.y && mouseX < wCoord.y + widg.height;
}
}
